阿里BaBa電腦筆記

'獲取用戶真實IP函數
Function GetIP()
    GetIP = Request.ServerVariables("HTTP_X_FORWARDED_FOR")
    If GetIP = "" Then GetIP = Request.ServerVariables("REMOTE_ADDR")
End Function
'獲取完整地址欄地址
Function GetUrl()
    GetUrl="http://"&Request.ServerVariables("SERVER_NAME")&Request.ServerVariables("URL")
    If Request.ServerVariables("QUERY_STRING")<>"" Then GetURL=GetUrl&"?"& Request.ServerVariables("QUERY_STRING")
End Function
 
'獲取本頁文件名
Function SelfName()
    SelfName = Mid(Request.ServerVariables("URL"),InstrRev(Request.ServerVariables("URL"),"/")+1)
End Function
'獲取文件後綴名
Function GetExt(filename)
    GetExt = Mid(filename,InstrRev(filename,".")+1)
End Function
'過濾不良字符
Function ChkBadWords(fString)
    Dim BadWords,bwords,i
    BadWords = "|王八|洪志"
    If Not(IsNull(BadWords) or IsNull(fString)) Then
    bwords = Split(BadWords, "|")
    For i = 0 to UBound(bwords)
        fString = Replace(fString, bwords(i), string(Len(bwords(i)),"*"))
    Next
    ChkBadWords = fString
    End If
End Function
'防止外部提交
Function ChkPost()
    Dim URL1,URL2
    ChkPost = False
    URL1 = Cstr(Request.ServerVariables("HTTP_REFERER"))
    URL2 = Cstr(Request.ServerVariables("SERVER_NAME"))
    If Mid(URL1,8,Len(URL2))<>URL2 Then
        ChkPost = False
    Else
        ChkPost = True
    End If
End Function
'清除HTML標記
Function stripHTML(strHTML)
    Dim objRegExp,strOutput
    Set objRegExp = New Regexp
    objRegExp.IgnoreCase = True
    objRegExp.Global = True
    objRegExp.Pattern = "<.+?>"
    strOutput = objRegExp.Replace(strHTML,"")
    strOutput = Replace(strOutput, "<","<")
    strOutput = Replace(strOutput, ">",">")
    stripHTML = strOutput
    Set objRegExp = Nothing
End Function